::  Этот скрипт сделан на основе файла dhcpconfig.cmd Франка-Петера Шульце
::  http://www.fpschultze.de/modules/smartfaq/faq.php?faqid=76
::  для проекта "Терминальная сеть" Николаем Иванюшиным
::  http://www.itadvisor.ru

@Echo Off
SetLocal

:: ------------------------------------------------------------------
:: эту часть файла необходимо отредактировать

:: Полное доменное имя (FQDN) и IP-адрес DHCP сервера
Set dhcpserver.dns=
Set dhcpserver.ip=

:: IP-адрес области, маска подсети, имя и (опционально) описание
Set scope.address=
Set scope.netmask=
Set scope.name=
Set scope.description=

:: Диапазон IP-адресов, которые dhcp сервер будет выдавать клиентам
Set iprange.startip=
Set iprange.endip=

:: Опции области (несколько ip-адресов разделяются пробелом)
Set 003router.array=
Set 006dnsserver.array=
Set 066bootserver.array=
Set 067bootfile.array=pxelinux.0

:: Активация,деактивация нового диапазона (0=деакт., 1=акт.)
Set scope.state=0

:: ------------------------------------------------------------------
:: далее не редактируйте


:: ------------------------------------------------------------------
:: Авторизуем DHCP в AD

If Defined dhcpserver.dns If Defined dhcpserver.ip (
  Netsh dhcp add server %dhcpserver.dns% %dhcpserver.ip%
) || Goto End


:: ------------------------------------------------------------------
:: Создаем новую область DHCP

If Defined scope.address If Defined scope.netmask If Defined scope.name (
  Netsh dhcp server %dhcpserver.ip% add scope %scope.address% %scope.netmask% %scope.name%
) || Goto End


:: ------------------------------------------------------------------
:: Задаем диапазон IP-адресов

If Defined iprange.startip If Defined iprange.endip (
  Netsh dhcp server %dhcpserver.ip% scope %scope.address% add iprange %iprange.startip% %iprange.endip%
) || Goto End


:: ------------------------------------------------------------------
:: Устанавливаем опцию 003 (Router)

If Defined 003router.array (
  Netsh dhcp server %dhcpserver.ip% scope %scope.address% set optionvalue 003 IPADDRESS %003router.array%
) || Goto End


:: ------------------------------------------------------------------
:: Устанавливаем опцию 006 (DNS servers)

If Defined 006dnsserver.array (
  Netsh dhcp server %dhcpserver.ip% scope %scope.address% set optionvalue 006 IPADDRESS %006dnsserver.array%
) || Goto End

:: ------------------------------------------------------------------
:: Устанавливаем опцию 066 (Boot Server Host Name)

If Defined 066bootserver.array (
  Netsh dhcp server %dhcpserver.ip% scope %scope.address% set optionvalue 066 IPADDRESS %066bootserver.array%
) || Goto End

:: ------------------------------------------------------------------
:: Устанавливаем опцию 067 (Bootfile Name)

If Defined 067bootfile.array (
  Netsh dhcp server %dhcpserver.ip% scope %scope.address% set optionvalue 067 STRING %067bootfile.array%
) || Goto End

:: ------------------------------------------------------------------
:: Активируем новую область

If Defined scope.state (
  Netsh dhcp server %dhcpserver.ip% scope %scope.address% set state %scope.state%
) || Goto End


:End
endlocal
