::  Этот скрипт сделан для проекта "Терминальная сеть" Николаем Иванюшиным
::  © 2009 http://www.itadvisor.ru

@Echo Off
SetLocal

:: ------------------------------------------------------------------
:: Копируем файл tftpd.exe в %windir%\system32
if exist windir%\system32\dllcache\tftpd.exe (
	copy /y %windir%\system32\dllcache\tftpd.exe %windir%\system32\tftpd.exe
)
if %PROCESSOR_ARCHITECTURE%==x86 (
	copy /y x86\tftpd.exe %windir%\system32\tftpd.exe
) else (
if %PROCESSOR_ARCHITECTURE%==AMD64 (
			copy /y x64\tftpd.exe %windir%\system32\tftpd.exe
			)
)

:: ------------------------------------------------------------------
:: Создаем службу Tftpd
sc create Tftpd start= auto binPath= %windir%\system32\tftpd.exe


:: ------------------------------------------------------------------
:: Создаем каталог tftpboot в корне системного диска
md %SYSTEMDRIVE%\tftpboot > nul: 2>&1

:: ------------------------------------------------------------------
:: Ограничиваем доступ к каталогу tftpboot
echo y|cacls %SYSTEMDRIVE%\tftpboot /g administrators:f system:f > nul: 2>&1

:: ------------------------------------------------------------------
:: Копируем загрузочные и конфигурационные файлы в каталог tftpboot
xcopy ..\tftpboot\*.* %SYSTEMDRIVE%\tftpboot\ /s /e 

:: ------------------------------------------------------------------
:: Задаем рабочий каталог службы Tftpd
echo REGEDIT4 > %SYSTEMDRIVE%\$DelReg$.reg
echo [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\Tftpd\Parameters] >> %SYSTEMDRIVE%\$DelReg$.reg
echo "Directory"="%SYSTEMDRIVE%\\tftpboot" >> %SYSTEMDRIVE%\$DelReg$.reg
:: альтернативный способ сделать то же самое
::reg add hklm\system\currentcontrolset\services\tftpd\Parameters
::reg add hklm\system\currentcontrolset\services\tftpd\Parameters /v Directory /t REG_SZ /d %SYSTEMDRIVE%\tftpboot
start/wait regedit -s %SYSTEMDRIVE%\$DelReg$.reg

:: ------------------------------------------------------------------
:: Удаляем временные файлы
del %SYSTEMDRIVE%\$DelReg$.reg > nul: 2>&1

:: ------------------------------------------------------------------
:: Запускаем службу Tftpd
sc start tftpd
